This blog is by design...

Report of all users with a mailbox, mail server name & store name

2006-03-22T11:29:00.000-05:00

By taking my lost post we can easily modify that to give us a basic report of all users along with with the mail server their mailbox resides on and which mail store their mailbox is in. Although it's possible to clip the CN= out of the results using vbscript, it's much easier to just import the text file that gets created into excel, select the entire column and do a replace on CN= and simply put nothing in the replace line. This nicely and neatly removes the CN= value allowing you to better sort. You can also clip any uneeded columns in there as well as there will be several that will likely be of no use. When importing the file into excel select both the comma and the semicolon as delimeters. Enjoy!

'***************************************************
'Kris Waters, http://krisdev.blogspot.com
Const ForWriting = 2
Const OpenAsASCII = 0
strOutputFile = "c:\Mail_report.txt"

Set objRootDSE = GetObject("LDAP://rootDSE")
strDomain = "LDAP://"& objRootDSE.Get("defaultNamingContext")

Set objFSO = CreateObject("scripting.filesystemobject")
Set objOutputFile = objFSO.CreateTextFile _
(strOutputFile, ForWriting, OpenAsASCII)

Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"

Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection

objCommand.CommandText = "<"& strDomain &">;(objectCategory=person)" & _
";distinguishedName,cn;subtree"
objCommand.Properties("Page Size") = 6000

Set objRecordSet = objCommand.Execute

While Not objRecordSet.EOF

strUserDN = objRecordSet.Fields("DistinguishedName")
set objUser = GetObject("LDAP://"& strUserDN)

If instr(objUser.homemdb,"CN=") <> 0 then
objOutputfile.writeline objUser.sn & ";" & _
objUser.givenName &";"& objUser.homemdb
End If

objRecordSet.Movenext

Wend

Wscript.Echo "All Done"

objOutputFile.close

For all users that have an Exchange mailbox, write ALL their email addresses to a file

2006-03-20T10:36:00.000-05:00

Although this can be done with ldifde, or possibly with csvde, I've never been terribly skillful with either of those utilities. So, this little vbscript will scrub your AD looking for anyone that has a value in the homemdb attribute. This generally means they have a mailbox on an exchange server somewhere, and thus should have an smtp addres in the proxyAddresses value in AD. This script does user accounts only, not contacts, groups, or anything else that might have an smtp address. If you're trying to search your domain for a particular smtp address to see where it's being used I have a script that does that as well, located here.

This is a pretty standard script, it uses a sql type query to gather all user accounts, then does some standard looping to sort out the ones that actually have mailboxes. Since the proxyAddresses attribute is 'multivalued', meaning that it can hold more than one entry, we have to sort through all the possible entries for that value. I also incorporated some string searches to drop the X400 address and any holdover MBX values so we get a nice list of JUST smtp addresses.
'***************************************************

On Error Resume Next
Const ForWriting = 2
Const OpenAsASCII = 0
strOutputFile = "c:\SmtpAdds.txt"

Set objRootDSE = GetObject("LDAP://rootDSE")
strDomain = "LDAP://"& objRootDSE.Get("defaultNamingContext")

Set objFSO = CreateObject("scripting.filesystemobject")
Set objOutputFile = objFSO.CreateTextFile _
(strOutputFile, ForWriting, OpenAsASCII)

Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"

Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection

objCommand.CommandText = "<"& strDomain &">;(objectCategory=person)" & _
";distinguishedName,cn;subtree"
objCommand.Properties("Page Size") = 6000

Set objRecordSet = objCommand.Execute

While Not objRecordSet.EOF
strUserDN = objRecordSet.Fields("DistinguishedName")
set objUser = GetObject("LDAP://"& strUserDN)

If instr(objUser.homemdb,"CN=") <> 0 then
objOutputfile.writeline objUser.displayName

For Each entry in objUser.GetEx("proxyAddresses")

If instr(entry,"X400") = 0 Then
proxy1 = entry

If instr(proxy1, "MBX:") = 0 Then
objOutputfile.writeline proxy1
End If
End If

Next
objOutputfile.writeline
End If

objRecordSet.MoveNext

Wend

objConnection.Close

Set objRootDSE = Nothing
set objConnection = Nothing
set objCommand = Nothing
set objRecordSet = Nothing
set objUser = Nothing
set objOutputFile = Nothing
set objFSO = Nothing

wscript.Echo "All Done"

AD Exchange Mailbox Quota Report

2006-03-14T13:41:00.000-05:00

The following vbscript will generate a report of all mailbox enabled users in Active Directory who have the 'Use mailbox store defaults' tickbox UN checked. It will also give you the value, if any, that is set in the 'Issue warning at (KB)' field and the 'Prohibit send at (KB)' fields. Enjoy!

'******************************************************
Set objRootDSE = GetObject("LDAP://rootDSE")
strDomain = "LDAP://"& objRootDSE.Get("defaultNamingContext")

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objOutputFile=objFSO.CreateTextFile("c:\MBQuotas.txt",True)

Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"

Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection

objCommand.CommandText = "<"& strDomain &">;"& _
"(objectCategory=user)" & _
";distinguishedName,displayName,mDBUseDefaults,homemdb,"& _
"mDBOverQuotaLimit,mDBStorageQuota;subtree"

objCommand.Properties("Page Size") = 6000

Set objRecordSet = objCommand.Execute

While Not objRecordSet.EOF

'Make sure there is NO linewrap in the following line
if objRecordSet.Fields("mDBUseDefaults") = FALSE AND objRecordSet.Fields("homemdb") <> "" then

strOutput = objRecordSet.Fields("displayName") & ";" & _
objRecordSet.Fields("mDBOverQuotaLimit") & _
";" & objRecordSet.Fields("mDBStorageQuota")
objOutputFile.WriteLine strOutput
end if
objRecordSet.MoveNext
Wend

wscript.Echo "All Done"

Breckenridge, CO - Christmas 2005

2006-02-01T12:20:00.000-05:00

Change AD info for users from File - vbscript, csv

2006-01-30T14:08:00.000-05:00

The following script was written for someone who had an interesting situation. He had a list of numerous users within his domain (not contained within a single OU) whose phone numbers and fax numbers needed to be changed. So, what we started with here was a csv file with a samAccountname (NT style login name), the new phone number and the new fax number in a csv file, in the following example format:
ssmith,999-9999,888-8888

The goal was then to have a script read this file and change the phone number (telephoneNumber) and fax number (facsimileTelephoneNumber) accordingly. In case you don't know, having a vbscript read a file isn't a terribly big deal, but it really doesn't do the best job of processing information on a single line. For example, when we have ssmith,999-9999,888-8888 it isn't the easiest thing to say 'hey, there's actually 3 pieces of data on this line'. What we wind up having to do is use the comma (rather painfully) to extrapolate each piece of information out of the single one line string, assign it to a variable and commit the change to AD.

We begin by reading the file into an array, extracting the information we need for each change by manipulating the string, then using NameTranslate to convert the samAccountName (that we got from the file) into a distinguishedName, bind to the object, insert the new information and commit the changes.

Enjoy!

'**************************************************
On error resume next
'written by Kristina L. Waters
'1/24/2006
'**************************************************
Const ADS_NAME_INITTYPE_GC = 3
Const ADS_NAME_TYPE_USER_PRINCIPAL_NAME = 9
Const ADS_NAME_TYPE_NT4 = 3
Const ADS_NAME_TYPE_1779 = 1 'Distinguished Name

strFile = "c:\users.csv"

'**************************************************
'Determine DNS Domain Name
Set objRootDSE = GetObject("LDAP://RootDSE")
strDNSDomain = objRootDSE.Get("defaultNamingContext")

'**************************************************
' Use the NameTranslate object to find the NetBIOS
' domain name from the DNS domain name.
Set objTrans = CreateObject("NameTranslate")
objTrans.Init ADS_NAME_INITTYPE_GC, strDNSDomain
objTrans.Set ADS_NAME_TYPE_1779, strDNSDomain
strNetBIOSDomain = objTrans.Get(ADS_NAME_TYPE_NT4)

'The following removes the \ as in DOMAIN\ '
strNetBIOSDomain=Left(strNetBIOSDomain,Len(strNetBIOSDomain)-1)
'wscript.Echo strNetBiosDomain

Set fso = CreateObject("Scripting.FileSystemObject")
Set usrFile = Fso.OpenTextFile(strFile)

'make File into an Array
aData = Split(usrFile.Readall,vbcrlf)

For X=0 To UBound(aData)
strData=aData(x) 'Read in each line of array
'wscript.Echo x

'**************************************************
strUser = Left(strData,InStr(strData,",")-1)
'wscript.Echo strUser

objTrans.Init ADS_NAME_TYPE_1779, strNetBIOSDomain
objTrans.Set ADS_NAME_TYPE_NT4, strNetBIOSDomain & "\" & strUser
strUserDN = objTrans.Get(ADS_NAME_TYPE_1779)

'**************************************************
set objUser = GetObject("LDAP://"& strUserDN)
'wscript.Echo objUser.displayName

If InStr(LCase(strData),LCase(objUser.samAccountname)) Then

'Remove the username from the string
strData=Mid(strData,InStr(strData,",")+1)

'Extract the phone number
strPhone=Left(strData,InStr(strData,",")-1)

'Extract the fax
strFax=Mid(strData,InStr(strData,",")+1)

objUser.telephoneNumber = strPhone
objUser.facsimileTelephoneNumber = strFax

'uncomment the line (remove the tick at beginning) to commit changes!
'objUser.setinfo info!

End If

'****************************
Next

set objRootDSE = nothing
set objTrans = nothing
set objOu = nothing
set fso = nothing
set usrFile = nothing

wscript.Echo "All Done"
'****************************

Add users to a group from a CSV file

2006-01-06T12:06:00.000-05:00

Here's another that I'm posting per request. This one comes in handy for me quite often. It can be modified to read in (from the file) samAccountnames, the smtp address, just about anything that can be converted using the name translate method. Here's a link that talks about some of the things you can do with IADsNameTranslate. Read through the script to see what attributes you need to modify to get it to work for you. Enjoy!

'------------------------------------------------------
'Use any and all scripts from this site at your own risk
'Test test test!
'This script will take a csv file of samAccountnames (ntname)
'and add all the users to the specified group.

'By KLW, 08/26/05

On Error Resume Next

Const ADS_PROPERTY_CLEAR = 1
Const ADS_PROPERTY_UPDATE = 2
Const ADS_PROPERTY_APPEND = 3
Const ADS_PROPERTY_DELETE = 4

Const ADS_NAME_INITTYPE_GC = 3

Const ADS_NAME_TYPE_USER_PRINCIPAL_NAME = 9
Const ADS_NAME_TYPE_NT4 = 3
Const ADS_NAME_TYPE_1779 = 1 'Distinguished Name

'----------------------------------------------------------
'Replace the below item with the security group
'or dist list you want modified
'Modify the dc=microsoft,dc=com to match your domain
Const strGroup = "LDAP://CN=IT Dept,OU=Distribution " _
& "Lists,OU=Exchange,DC=microsoft,DC=com"
Set objGroup = GetObject(strGroup)

'Replace this item with the list of users
Const strFile = "c:\users.csv"

'---------------------------------------------------------
set objReadFSO = CreateObject ("Scripting.FileSystemObject")
set objUsersFile = objReadFSO.OpenTextFile(strFile)

'---------------------------------------------------------
'Determine DNS Domain Name
Set objRootDSE = GetObject("LDAP://RootDSE")
strDNSDomain = objRootDSE.Get("defaultNamingContext")

'--------------------------------------------------------
' Use the NameTranslate object to find the NetBIOS
' domain name from the DNS domain name.
Set objTrans = CreateObject("NameTranslate")
objTrans.Init ADS_NAME_INITTYPE_GC, strDNSDomain
objTrans.Set ADS_NAME_TYPE_1779, strDNSDomain
strNetBIOSDomain = objTrans.Get(ADS_NAME_TYPE_NT4)

'The following removes the \ as in DOMAIN\
strNetBIOSDomain = Left(strNetBIOSDomain, Len(strNetBIOSDomain) - 1)
'wscript.Echo strNetBiosDomain

'------------------------------------------------------
do while objUsersFile.AtEndOfStream = False
strUser = rtrim(Ucase(objUsersFile.readLine))

objTrans.Init ADS_NAME_TYPE_1779, strNetBIOSDomain
objTrans.Set ADS_NAME_TYPE_NT4, strNetBIOSDomain & "\" & strUser
strUserDN = objTrans.Get(ADS_NAME_TYPE_1779)

'wscript.Echo strUserDN
set objUser = GetObject("LDAP://"& strUserDN)
strDNPath = objUser.distinguishedName

objGroup.PutEx ADS_PROPERTY_APPEND, "member", Array(strDNPath)
objGroup.SetInfo
Loop

'----------------------------------------------------
wscript.echo "All Done"

set objUser = Nothing
set objGroup = Nothing
set objUsersFile = Nothing
set objReadFSO = Nothing
set objRootDSE = Nothing
set objTrans = Nothing

Can I allow more than one person to manage a Windows distribution list? Yes!

2005-12-01T13:52:00.000-05:00

Short answer, yes. In a Windows 2000 domain (not sure if this restriction is exactly the same in a 2003 domain), let's say you have a distribution list called ALLIT, which you manually add people to when needed. You have several administrative assistants. Normally, admin1 updates the list, as he has been set as the manager of the list from within Active Directory Users & Computers (ADUC), using the Managed By tab in the properties of the group.

What happens when admin1 is out sick, on vacation, etc? Your boss would like admin1, admin2, AND admin3 to be able to update the list. But, the problem is that you can only select a single user in the Managed By tab. So what do you do? There's a pretty easy way to get around this. First off, you need to be familiar with ADSI edit which you should be if you're an admin for a 2000/2003 domain. There are lots of links and information that will tell you that ADSI edit is terribly dangerous. Well, just about any admin tool can be terribly dangerous if used the wrong way. Personally, I find ADSI edit invaluable, just be careful until you become familiar with it. Here's a quick tutorial: ADSI_EDIT.

What you need to do first is find (or create) a group that contains all the users who should be able to update the given list. In our case, we're going to create a security group called 'ALLIT Update' and add admin1, admin2 and admin3 to the group.

Next, head into ADSI edit, right click and select 'Connect To well known naming context' and make sure 'Domain' is in the drop down list. Expand things out and you should see a structure that looks like your OU structure when you're in the ADUC. Find the 'ALLIT Update' group, right click and select properties, scroll down til you find the distinguishedName attribute, double click it and copy the value.

Next, find the ALLIT group in ADSI edit and find the managedBy value. Paste the distinguishedName value from 'ALLIT Update' into this field, exit, head back into the ADUC, find ALLIT and you should now see the 'ALLIT Update' listed in there as the group manager. All you need to do now is tick the 'manager can update group membership' checkbox. Now admin1, admin2 and admin3 should be able to manager the ALLIT group. (if they can't do it right away, wait just a bit - have them log off/back on then try again). You also have the added convenience of merely adding people to and from 'ALLIT Update' whenever you want to add/remove group managers.

Enjoy!
Kris

Enumerate AD group using NT Name and NameTranslate Method

2005-11-22T13:40:00.000-05:00

This is a revision on my earlier post today. It was noted that
the first post didn't pick up contacts. I revised this one so it
will pick up any object in the dist list.

'***************************************************
'The constant below should reflect the name of the group
'you wish to enumerate. For a Distribution group, you must
'use the 'alias' name rather than the display name of the group
'See ADUsers and computers to find the alias name of a dist group

Const strGroup = "ITNET"

'This will create a file in a folder called c:\reports. Either create
'the folder or change the hardcoded path down below
'***************************************************
On Error Resume Next
Const ADS_NAME_INITTYPE_GC = 3
Const ADS_NAME_TYPE_USER_PRINCIPAL_NAME = 9
Const ADS_NAME_TYPE_NT4 = 3
Const ADS_NAME_TYPE_1779 = 1 'Distinguished Name

Set objRootDSE = GetObject("LDAP://rootDSE")
Set objDomainRoot = GetObject("LDAP://"& _
objRootDSE.Get("defaultNamingContext"))
strDomain = Right(objDomainRoot.Name, Len(objDomainRoot.Name)-3)
'wscript.Echo strDomain

Set filesys = CreateObject("Scripting.FileSystemObject")
Set memberfile = filesys.CreateTextFile("c:\Reports\"& _
strGroup &".txt", True)

Set objTrans = CreateObject("NameTranslate")

'********************
'translate NT group name into AD DistinguishedName

objTrans.Init ADS_NAME_TYPE_1779, strDomain
objTrans.Set ADS_NAME_TYPE_NT4, strDomain & "\" & strGroup
strGroupDN = objTrans.Get(ADS_NAME_TYPE_1779)
'wscript.Echo strGroupDN
'*********************

set objGroup = GetObject("LDAP://"& strGroupDN)
'wscript.Echo objGroup.displayName

arrMember = objGroup.GetEx("member")
For Each User in arrMember
'WScript.Echo vbTab & User

set objUser = GetObject("LDAP://"& User)
set objProxy = GetObject("LDAP://"& objUser.distinguishedName)

For Each proxyAddresses in objProxy.GetEx("proxyAddresses")
If Instr(proxyAddresses, "SMTP:") then
strEmail = Right(proxyAddresses, Len(proxyAddresses)-5)
End If
Next

memberfile.Writeline objUser.mailNickName & "," & strEmail
Next
memberfile.close

set objRootDSE = Nothing
set objDomainRoot = Nothing
set filesys = Nothing
set memberfile = Nothing
set objTrans = Nothing
set objGroup = Nothing
set userObj = Nothing
set objProxy = Nothing

wscript.Echo "All Done"

Enumerate Group Membership, Print SMTP address in File - VBSCRIPT

2005-11-22T09:53:00.000-05:00

The script below was done per request, it will print the
samAccountName and PRIMARY smtp address (if there is one)
for all users in a given group (distribution or security,
doesn't matter.)

The script will put them in a folder called C:\Reports,
you need to either create that folder on your C: drive
or edit the code to place the file where you'd like it
to go.

I used a few different methods in this one, mixing some
NT methods in, and threw in some name translate methods.
It was fun to write.

Enjoy!

'**************************************************
'The constant below should reflect the name of the group
'you wish to enumerate. For a Distribution group, you must
'use the 'alias' name rather than the display name of the group
'See ADUsers and computers to find the alias name of a dist group

Const strGroup = "ALLUSERS"

'This will create a file in a folder called c:\reports. Either create
'the folder or change the hardcoded path down below
'**************************************************
On Error Resume Next
Const ADS_NAME_INITTYPE_GC = 3
Const ADS_NAME_TYPE_USER_PRINCIPAL_NAME = 9
Const ADS_NAME_TYPE_NT4 = 3
Const ADS_NAME_TYPE_1779 = 1 'Distinguished Name

Set objRootDSE = GetObject("LDAP://rootDSE")
Set objDomainRoot = GetObject("LDAP://"& _
objRootDSE.Get("defaultNamingContext"))
strDomain = Right(objDomainRoot.Name, Len(objDomainRoot.Name)-3)
'wscript.Echo strDomain

Set filesys = CreateObject("Scripting.FileSystemObject")
Set memberfile = filesys.CreateTextFile("c:\Reports\"& _
strGroup &".txt", True)

Set objTrans = CreateObject("NameTranslate")
Set objGroup = GetObject("WinNT://" & _
strDomain & "/" & strGroup & ",group")

For Each objMember In objGroup.Members
username = objMember.Name
Set UserObj = GetObject("WinNT://"& _
strDomain & "/" & username)
displayname = userobj.fullname

strUser = rtrim(Ucase(username))

objTrans.Init ADS_NAME_TYPE_1779, strDomain
objTrans.Set ADS_NAME_TYPE_NT4, strDomain & "\" & strUser
strUserDN = objTrans.Get(ADS_NAME_TYPE_1779)
set objUser = GetObject("LDAP://"& strUserDN)
set objProxy = GetObject("LDAP://"& objUser.distinguishedName)

For Each proxyAddresses in objProxy.GetEx("proxyAddresses")
If Instr(proxyAddresses, "SMTP:") then
strEmail = Right(proxyAddresses, Len(proxyAddresses)-5)
End If
Next

memberfile.Writeline strUser & "," & strEmail
Next
memberfile.close

set objRootDSE = Nothing
set objDomainRoot = Nothing
set filesys = Nothing
set memberfile = Nothing
set objTrans = Nothing
set objGroup = Nothing
set userObj = Nothing
set objProxy = Nothing

wscript.Echo "All Done"

Search your domain for a particular smtp email address, or 'proxyAddresses'

2005-09-01T15:45:00.000-04:00

'********************************************
'script to search a domain for a particular SMTP address. searches
'users, groups and public folders. might not search against default
'users container, i don't use it and didn't test against it.
'Just modify the strAddress line to contain the address you're searching for
'thanks to EE's Chris-Dent for his OURecurse subroutine
'written by EE's kristinaw, 05/20/05

strAddress = lcase("SMTP:kris@norfolk.gov")
strFound = FALSE

Set objRootDSE = GetObject("LDAP://rootDSE")
Set objDomainRoot = GetObject("LDAP://"& _
objRootDSE.Get("defaultNamingContext"))

wscript.Echo "Searching for address "& strAddress

For Each objItem in objDomainRoot
If strFound = FALSE Then
'wscript.Echo objitem.Name
If objItem.Class="organizationalUnit" Then
'wscript.Echo objItem.ADSPath
OURecurse objItem.ADSPath
End If

If objItem.Class="user" Then
'wscript.Echo objItem.name
ProcessUsers objItem
End If

If objItem.Class="group" Then
ProcessUsers objItem
End If

'The below portion of code searches public folders
If objItem.cn ="Microsoft Exchange System Objects" then
'wscript.Echo objItem.Name
OURecurse objItem.ADSPath
End If
End If
Next

wscript.Echo "All Done"

Set objRootDSE = Nothing
Set objDomainRoot = Nothing

'**********************************************
Sub ProcessUsers(objUsers)
On Error Resume Next

'wscript.Echo objUsers.Name
set objProxy = GetObject("LDAP://"& objUsers.distinguishedName)
For Each proxyAddresses in objProxy.GetEx("proxyAddresses")
If lcase(proxyAddresses) = strAddress then
If objProxy.Class="publicFolder" then

wscript.Echo "Proxy address "& _
strAddress &" is assigned to a Public Folder named '"& _
objProxy.displayName &"', "&"in Public Folder Path "& _
objProxy.folderPathname

Else

wscript.Echo "Proxy address "& _
strAddress &" is assigned to the user or group "& _
"with a samAccountName of '"& objProxy.saMAccountName & _
"' and a display name of "& objProxy.displayName

End If
strFound = TRUE
End If
Next

set objProxy = Nothing

End Sub

'**********************************************
Sub OURecurse(objFirst)

' This OU is responsible for going through the AD Structure

Dim objOrgUnit, objItem

Set objOrgUnit = GetObject(objFirst)
For Each objItem in objOrgUnit
If objItem.Class="user" Then
'wscript.Echo objItem.Name
ProcessUsers objItem
End If

If objItem.Class="group" Then
ProcessUsers objItem
End If

If objItem.Class="publicFolder" Then
ProcessUsers objitem
End If

If objItem.Class="organizationalUnit" Then
'wscript.Echo objItem.Name
OURecurse objItem.ADSPath
End If
Next

Set objOrgUnit = Nothing
Set objFirst = Nothing

End Sub

'********************************************

Another Mailbox Size Mod

2005-08-18T10:53:00.000-04:00

Per request, this one just prints the down and dirty, mailbox name and size. This works on Ex2003 only.

'**************************************************
On Error Resume Next
'Written to a file instead of Echoed on the screen

set objReadFSO = CreateObject ("Scripting.FileSystemObject")
set objOutputFile = objReadFSO.CreateTextFile("c:\Mailboxes.txt")

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & _
"\ROOT\MicrosoftExchangeV2")

Set colItems = objWMIService.ExecQuery _
("Select * from Exchange_Mailbox")

For Each objItem in colItems

objOutputFile.Writeline objItem.MailboxDisplayName & _
"," & objItem.Size

Next

objOutputFile.Close

set objReadFSO = Nothing
set objOutputFile = Nothing
Set objWMIService = Nothing
Set colItems = Nothing

Wscript.Echo "All Done"

List Exchange 2003 Mailbox Information

2005-08-17T09:51:00.000-04:00

The following script is a small modification on the MS script posted here: List Exchange Mailbox Information
This simply causes the script to output the information to a text file rather than echoing it to the screen. If you need historical tracking, or mailbox growth tracking, I believe Glen Scales has an excellent script for such things on his Blog, but then again, all his scripts and programs are excellent IMHO.

'**************************************************
On Error Resume Next
'Written to a file instead of Echoed on the screen

set objReadFSO = CreateObject ("Scripting.FileSystemObject")
set objOutputFile = objReadFSO.CreateTextFile("c:\Mailboxes.txt")

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & _
"\ROOT\MicrosoftExchangeV2")

Set colItems = objWMIService.ExecQuery _
("Select * from Exchange_Mailbox")

For Each objItem in colItems
objOutputFile.Writeline "Associated content count: " & _
objItem.AssocContentCount

objOutputFile.Writeline "Date discovered absent in DS: " & _
objItem.DateDiscoveredAbsentInDS

objOutputFile.Writeline "Delete messages size extended: " & _
objItem.DeletedMessageSizeExtended

objOutputFile.Writeline "Last logged-on user account: " & _
objItem.LastLoggedOnUserAccount

objOutputFile.Writeline "Last logoff time: " & _
objItem.LastLogoffTime

objOutputFile.Writeline "Last logon time: " & _
objItem.LastLogonTime

objOutputFile.Writeline "Legacy distinguished name: " & _
objItem.LegacyDN

objOutputFile.Writeline "Mailbox display name: " & _
objItem.MailboxDisplayName

objOutputFile.Writeline "Mailbox GUID: " & _
objItem.MailboxGUID

objOutputFile.Writeline "Server name: " & _
objItem.ServerName

objOutputFile.Writeline "Size: " & _
objItem.Size

objOutputFile.Writeline "Storage group name: " & _
objItem.StorageGroupName

objOutputFile.Writeline "Storage limit information: " & _
objItem.StorageLimitInfo

objOutputFile.Writeline "Store name: " & _
objItem.StoreName

objOutputFile.Writeline "Total items: " & _
objItem.TotalItems

objOutputFile.Writeline

Next

objOutputFile.Close

set objReadFSO = Nothing
set objOutputFile = Nothing
Set objWMIService = Nothing
Set colItems = Nothing

Wscript.Echo "All Done"

2005-06-29T10:33:00.000-04:00

I'm in a Citrix Presentation Server class this week, so no time for new postings. But in the meantime, visit my resume by clicking here.

2005-06-22T09:36:00.000-04:00

ADModify.Net

Bulk changes to the "Delivery Restrictions" field with ADModify

2005-06-22T09:09:00.000-04:00

Just to build on my last post, why do something by hand or write a script when the Exchange folks have been kind enough to write a nice little GUI utility to help you make bulk changes? Not sure about you all, but I'd much rather be playing Counterstrike than sitting around clicking a thousand users to make the same change on all of them. Wouldn't you?

So anyways, this neat little tool is called ADModify, and you can download it here. I won't write too much about it since the team over at EHLO has already done that, which makes sense since they wrote it! But, for the script in my previous post, all you'd need to do to make the same change is run ADModify.Net, get to the screen above (the Custom field)(sorry the pic is so small) and for this particular example you would enter dlMemSubmitPerms in the Attribute Name field, and the DN, or distinguished name of the value we want to add. So we would add CN=ALLMAIL,OU=DistLists,DC=domain,DC=com for a group called ALLMAIL in and OU called DistLists in a a domain called 'domain.com'. For this value you also have to check the 'Multivalued Append' box, which is necessary for any attribute that can hold more than one value. To add the second group in our example you'd just finish adding the first one then rerun the utility.

But, don't listen to my ramblings, check out Dan Winter's post on the subject over at EHLO for more information

Enjoy!

2005-06-21T17:11:00.000-04:00

Beach Party

"How to edit Exchange AD Attributes for multple users" or "How to bulk populate the Message Restrictions tab in AD"

2005-06-20T12:20:00.000-04:00

I've been asked such questions numerous times. It's usually asked by an admin in an environment such as a school where abuse of the email system is rampant, to say the least. Often the admin wants to be able to restrict the end user such that he can receive messages on from a particular AD group. In a school, for example, you could have a group that contains all teachers and staff members. You can then go into the ADUC properties for a selected user, select the Exchange general tab, Delivery restrictions, Message Restrictions, select the 'Only From' radio button, and enter the teachers/staff members group in this area. This will effectively prevent students from emailing each other, since they're only allowed to receive emails from members of the authorized group (teachers). Now, if you have a large number of users, you're probably not going to want go into the properties for each user and make this change.

I had originally written a little script to make this change en masse, but then found out about a little too that can handle it as well. First off, here's the script:

'*******************************************************
Const strOU = "LDAP://OU=Test OU,DC=domain,DC=com"
Const strGroup1 = "CN=ALLMAIL,OU=DistLists,DC=domain,DC=com"
Const strGroup2 = "CN=ALLIT,OU=DistLists,DC=domain,DC=com"

Set objOU = GetObject(strOU)
objOU.Filter = Array("user")

For Each objUser In objOU
'wscript.Echo objUser.Name
objUser.PutEx ADS_PROPERTY_APPEND, _
"dlmemSubmitPerms", Array(strGroup1,strGroup2)
objUser.SetInfo
Next

wscript.echo "All Done"
'*******************************************************

The script will put two groups called ALLMAIL and ALLIT in the aforementioned box (Accept messages only from) for all users in an OU called Test OU. Obviously you're going to have to change the DN's to match your own environment if you want this script to work for you.

I'm going to write a separate post on how to use ADModify to accomplish the same task.

Kris

Script to write all server names to a file using SQL type query

2005-06-17T10:34:00.000-04:00

This is a simple little script that will generate a text file of server and DC names sorted in alphabetical order. In my Win2K domain, all my servers (other than DC's, of course) reside in an OU called Servers that is in the root of my OU structure. I have several child OU's under the Servers OU, but this script accounts for that so we don't need to worry about doing any kind of OU recurse. We're just going to use a SQL type query to query the entire domain with an ADODB connection for any computer object with the word "Servers" in it's distinguishedName. I figured most people probably have a similar setup (all your servers in one OU), so just change the strServersCont variable to match the name of the OU you keep your servers in and the script should work for you as well.

I've also included code to pull in the names from the default Domain Controllers OU. We then use a totally separate recordset to sort the first recordset by name, and voila. We have a nice little text file, c:\servers.txt, with the names of all servers and all DC's. I have several other scripts that get their data from this text file and I didn't want to have to worry about updating the file every time we added/removed servers, so I have this script set up as a daily task. One less thing I have to worry about :)

'***************************************************
Const ForWriting = 2
Const OpenAsASCII = 0
strServersCont = "Servers"
strOutputFile = "c:\servers.txt"

Set objRootDSE = GetObject("LDAP://rootDSE")
strDomain = "LDAP://"& objRootDSE.Get("defaultNamingContext")

Set objFSO = CreateObject("scripting.filesystemobject")
Set objOutputFile = objFSO.CreateTextFile _
(strOutputFile, ForWriting, OpenAsASCII)

Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"

Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection

objCommand.CommandText = "<"& strDomain & _
">;(objectCategory=computer)" & ";distinguishedName,cn;subtree"
objCommand.Properties("Page Size") = 10000

Const adVarChar = 200 'specifies a string type data
Set objRecordsetNew = CreateObject("ADODB.Recordset")
objRecordsetNew.Fields.Append "ServerName", adVarChar, 50
objRecordsetNew.Open

Set objRecordSet = objCommand.Execute

While Not objRecordSet.EOF
if instr(objRecordSet.Fields("distinguishedName"), strServersCont) _
<> 0 OR instr(objRecordSet.Fields("distinguishedName"), _
"Domain Controllers")then
objRecordsetNew.AddNew
objRecordSetNew("ServerName") = objRecordset.Fields.Item("cn").Value
strCount = strCount + 1
end if
objRecordSet.MoveNext
Wend
objConnection.Close

objRecordSetNew.Sort = "ServerName ASC"

While Not objRecordSetNew.EOF
objOutputFile.writeline objRecordSetNew.Fields.Item("ServerName")
objRecordSetNew.Movenext
Wend

objOutputFile.Close

set objConnection = Nothing
set objCommand = Nothing
set objRecordSet = Nothing
set objRecordSetNew = Nothing
set objOutputFile = Nothing
set objFSO = Nothing
'*******************************************************

VBSCRIPT - For all domain users, write all their Delegate information to a file

2005-06-02T13:28:00.000-04:00

The following script will recurse (go through) your AD structure,
and for all user accounts it will take their Outlook delegate information
and write it out to a file. Until recently I didn't realize that delegate
information that was set inside the Outlook client was stored in AD, but
guess what. It is. Give it a try...

'*****************************************************
'you MAY NOT post this script on any other website
'you MAY post a link to the script, thus giving me my due credit for
'writing it.

Set objRootDSE = GetObject("LDAP://rootDSE")
Set objDomainRoot = GetObject("LDAP://"& _
objRootDSE.Get("defaultNamingContext"))

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objOutputFile = objFSO.CreateTextFile("c:\Delegates.txt", True)

For Each objItem in objDomainRoot
'wscript.Echo objItem.Name
If objItem.Class="organizationalUnit" Then
OURecurse objItem.ADSPath
end if

If objItem.Class="user" Then
'wscript.Echo objItem.name
ProcessUsers objItem
End If
Next

objOutputFile.Close
set objOutputFile = Nothing
set objRootDSE = Nothing
set objDomainRoot = Nothing
set objFSO = Nothing

wscript.Echo "All Done"

'***************************************************
Sub ProcessUsers(objUsers)
On Error Resume Next

'wscript.Echo objUsers.Name
set objPD = GetObject("LDAP://"& _
objUsers.distinguishedName)
objOutputFile.Writeline objPD.displayName
delegateList = objPD.GetEx("publicDelegates")
For Each Desc In delegateList
objOutputFile.Writeline Desc
Next
objOutputFile.Writeline

set objPD = Nothing

End Sub

'*************************************************
' This sub is responsible for going through the AD Structure

Sub OURecurse(objFirst)

Dim objOrgUnit, objItem

Set objOrgUnit = GetObject(objFirst)
For Each objItem in objOrgUnit
If objItem.Class="user" Then
'wscript.Echo objItem.Name
ProcessUsers objItem
End If

If objItem.Class="organizationalUnit" Then
'wscript.Echo objItem.Name
OURecurse objItem.ADSPath
End If
Next

Set objOrgUnit = Nothing

End Sub
'***************************************************

'you MAY NOT post this script on any other website
'you MAY post a link to the script, thus giving me my due credit for
'writing it.

2005-05-26T16:45:00.000-04:00

Me at the beach in May, Surf City, NC

Search your entire Domain for a particular smtp email address, or 'proxyAddresses' attribute

2005-05-26T15:37:00.000-04:00

I understand it can be pretty tricky to find an existing SMTP address, especially if that address is assigned to a group or Public Folder. Most of the solutions I've seen for this problem involve printing a list of all addresses in the domain and sorting through that by hand, or searching ONLY public folders, or only users, etc. Visit typepad for information on how to do these types of searches.

Although you might find these methods useful and not too time consuming if you're in a small domain, in a large domain this could take a while. And what if you only need to find what user/group/public folder a single address is assigned to? Who wants to wade through a ton of reports to find that single address? Anyways, I wrote a little vbscript to do it. To give you a little background, the email addresses you see listed under the E-mail addresses tab in the ADUC are stored in AD in what's called a 'multivalued' attribute. Meaning just what it says, this attribute can hold more than one value, meaning one user can have several different email addresses, or 'proxyAddresses'.

Anyways, to use the script just edit the first line so that it matches the address you're looking for (it's not case sensitive, and don't remove the SMTP portion!), save the file as search.vbs (or whatever.vbs) and double click. It may take a few minutes to run depending on how large your domain is, but if the address is assigned to a user, group or public folder, the script should find it.

strAddress = lcase("SMTP:anyone@domain.com")
strFound = FALSE

Set objRootDSE = GetObject("LDAP://rootDSE")
Set objDomainRoot = GetObject("LDAP://"& _
objRootDSE.Get("defaultNamingContext"))
wscript.Echo "Searching for address "& _
"SMTP:kris@norfolk.gov. Click OK to continue"

For Each objItem in objDomainRoot
If strFound = FALSE Then
'wscript.Echo objitem.Name
If objItem.Class="organizationalUnit" Then
'wscript.Echo objItem.ADSPath
OURecurse objItem.ADSPath
End If

If objItem.Class="user" Then
'wscript.Echo objItem.name
ProcessUsers objItem
End If

If objItem.Class="group" Then
ProcessUsers objItem
End If

'The below portion of code searches public folders
If objItem.cn ="Microsoft Exchange System Objects" then
'wscript.Echo objItem.Name
OURecurse objItem.ADSPath
End If
End If
Next

wscript.Echo "All Done"

Set objRootDSE = Nothing
Set objDomainRoot = Nothing

'*************************************************
Sub ProcessUsers(objUsers)
On Error Resume Next

'wscript.Echo objUsers.Name
set objProxy = GetObject("LDAP://"& objUsers.distinguishedName)
For Each proxyAddresses in objProxy.GetEx("proxyAddresses")
If lcase(proxyAddresses) = strAddress then
If objProxy.Class="publicFolder" then
wscript.Echo "Proxy address "& strAddress &" is assigned to a "& _
"Public Folder named '"& objProxy.displayName &"', "& _
"in Public Folder Path "& objProxy.folderPathname
Else
wscript.Echo "Proxy address "& strAddress &" is assigned "& _
"to the user or group with a samAccountName of '"& _
objProxy.saMAccountName &"' and a display name of "& _
objProxy.displayName
End If
strFound = TRUE
End If
Next

set objProxy = Nothing

End Sub

'**************************************************
Sub OURecurse(objFirst)

' This OU is responsible for going through the AD Structure

Dim objOrgUnit, objItem

Set objOrgUnit = GetObject(objFirst)
For Each objItem in objOrgUnit
If objItem.Class="user" Then
'wscript.Echo objItem.Name
ProcessUsers objItem
End If

If objItem.Class="group" Then
ProcessUsers objItem
End If

If objItem.Class="publicFolder" Then
ProcessUsers objitem
End If

If objItem.Class="organizationalUnit" Then
'wscript.Echo objItem.Name
OURecurse objItem.ADSPath
End If
Next

Set objOrgUnit = Nothing
Set objFirst = Nothing

End Sub
'**********************************************